apply plugin: 'com.android.application'
apply plugin: 'kotlin-android'
apply plugin: 'kotlin-android-extensions'
apply plugin: 'kotlin-kapt'
apply plugin: 'io.fabric'

buildscript {
    ext.anko_version = "0.10.1"
}

android {
    compileSdkVersion 26
    buildToolsVersion "26.0.2"

    defaultConfig {
        applicationId "jp.rhe.smileessence3"
        minSdkVersion 21
        targetSdkVersion 26

        versionName "git -C ${rootDir} describe --tags --long --dirty --always".execute().text.trim()
        versionCode "git -C ${rootDir} rev-list HEAD --count".execute().text.trim().toInteger()
        println "-----------VERSION----------"
        println "- CODE: " + getVersionCode()
        println "- NAME: " + getVersionName()
        println "----------------------------"
    }
    buildTypes {
        debug {
            applicationIdSuffix ".debug"
            ext.enableCrashlytics = false
        }
        release {
            applicationIdSuffix ".release"
            minifyEnabled false
            proguardFiles getDefaultProguardFile('proguard-android.txt'), 'proguard-rules.pro'
        }
    }
    lintOptions {
        abortOnError false
        checkReleaseBuilds false
    }
}

dependencies {
    compile "org.jetbrains.kotlin:kotlin-stdlib-jre7:$kotlin_version"

    compile 'com.android.support:support-core-ui:26.1.0'
    compile 'com.android.support:support-v13:26.1.0'

    // Anko; not using Anko Layouts and Anko SQLite for now
    compile "org.jetbrains.anko:anko-commons:$anko_version"
    compile "org.jetbrains.anko:anko-coroutines:$anko_version"

    // Volley
    compile 'com.android.volley:volley:1.0.0@aar'

    // Crouton
    compile('de.keyboardsurfer.android.widget:crouton:1.8.5@aar') {
        // exclusion is not necessary, but generally a good idea.
        exclude group: 'com.google.android', module: 'support-v4'
    }

    // PullToRefresh
    compile 'com.navercorp.pulltorefresh:library:3.3.0-SNAPSHOT@aar'

    // twitter4j
    compile 'org.twitter4j:twitter4j-core:4.0.6'
    compile 'org.twitter4j:twitter4j-media-support:4.0.6'
    compile 'org.twitter4j:twitter4j-stream:4.0.6'

    // Orma
    kapt "com.github.gfx.android.orma:orma-processor:4.2.5"
    compile 'com.github.gfx.android.orma:orma:4.2.5'

    // Fabric
    compile('com.crashlytics.sdk.android:crashlytics:2.6.8@aar') {
        transitive = true
    }

    // LeakCanary
    debugCompile 'com.squareup.leakcanary:leakcanary-android:1.5.4@aar'
    releaseCompile 'com.squareup.leakcanary:leakcanary-android-no-op:1.5.4@aar'
}

kotlin {
    experimental {
        coroutines "enable"
    }
}